actor HellGuard 15000
{
	//$Category "ZDoom Monster pack"
	  Spawnid 255
    Health 300
    Radius 24
    Height 64
    Speed 8
    PainChance 50
    Mass 500
    MONSTER 
    +FLOORCLIP
    SeeSound "hellguard/sight"
    PainSound "knight/pain"
    DeathSound "hellguard/death"
    ActiveSound "hellguard/idle"
    Obituary "%o was fried by a hell guard."
    MeleeDamage 8
    States
    {
    Spawn:
        HLGD AB 10 A_Look
        Loop
    See:
        HLGD AABBCCDD 3 A_Chase
        Loop
    Missile:
        HLGD E 8 A_FaceTarget
        HLGD F 0 A_Jump(85,4)
        HLGD F 0 A_Jump(128,2)
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, -4, 1)
        Goto Missile+6
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, 4, 1)
        Goto Missile+6
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, 0, 1)
        Goto Missile+6
        HLGD E 4 A_FaceTarget
        HLGD F 0 A_Jump(85,4)
        HLGD F 0 A_Jump(128,2)
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, -4, 1)
        Goto Missile+12
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, 4, 1)
        Goto Missile+12
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, 0, 1)
        Goto Missile+12
        HLGD E 4 A_FaceTarget
        HLGD F 0 A_Jump(85,4)
        HLGD F 0 A_Jump(128,2)
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, -4, 1)
        Goto See
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, 4, 1)
        Goto See
        HLGD F 4 Bright A_CustomMissile("HellGuardBall", 28, -8, 0, 1)
        Goto See
    Pain:
        HLGD G 2
        HLGD G 2 A_Pain
        Goto See
    Death:
        HLGD H 6
        HLGD I 6 A_Scream
        HLGD J 6
        HLGD K 6 A_Fall
        HLGD LM 6
        HLGD N -1
        Stop
    Raise:
        HLGD ONMLKJI 8
        Goto See
    }
}

actor HellGuardBall
{
    Radius 13
    Height 8
    Speed 10
    Damage 6
    PROJECTILE
    RENDERSTYLE ADD
    ALPHA 0.67
    SeeSound "hellguard/shot"
    DeathSound "hellguard/shothit"
    Decal PlasmaScorchLower
    States
    {
    Spawn:
        HGFB ABCD 2 Bright
        Loop
    Death:
        HGFB EFGH 4 Bright
        Stop
    }
}